Apri Cancello

Apricancello

Questa è la discussione originale.

Realizziamo qualcosa di pratico con il PPTEA e lo facciamo nella configurazione senza PC...quindi non sono necessari i collegamenti sulla porta usb ( occorrono solo per trasferisci il codice eabasic).

Il PPTEA in questa configurazione vive di vita propria e non scambia nessun dato con il PC. Il circuito permette di aprire un cancello (porta o anche altro) se viene inserita la combinazione esatta.

La combinazione scelta è: *1492#, mentre se viene inserita la combinazione *1493#viene aperto li cancello dopo 30 secondi...il motivo? Indovinate!

BIT UTILIZZATI:
BIT INGRESSO TASTIERA (0,1,2,3)
BIT USCITA TASTIERA (4,5,6)
BIT LED 7 (si accende ogni volta che si preme un pulsante o se è in attesa dei 30 secondi)
BIT APERTURA CANCELLO 8
Il codice è stato modificato e reso più leggibile ed occupa quasi tutta la memoria a disposizione del PPTEA (253 byte).

Questa è la discussione originale.

Questo è il file ".eab" dell'Apricancello.
Scarica il file (ZIP)

Questo è il filmato:

Questo è il codice:

10 'PPTEA APRICANCELLO VER 1.2- COMPONENTI UTILIZZATI: TASTIERA 4X3, Led , Rele'
15 'COMBINAZIONE: *1492# APRE IL CANCELLO(ASTERISCO UNO QUATTRO NOVE DUE CANCELLETTO), BIT INGRESSI TASTIERA (0,1,2,3), BIT USCITA TASTIERA (4,5,6), BIT ON
LED 7, BIT APERTURA CANCELLO 8
16 ' COMBINAZIONE:*1493# APRE IL CANCELLO RITARDANDO DI 30 SECONDI L'APERTURA
20 '------------CODICE TASTI-----------
21 CONSTANT TASTO_1=65
22 CONSTANT TASTO_2=33
23 CONSTANT TASTO_3=17
24 CONSTANT TASTO_4=66
25 CONSTANT TASTO_5=34
26 CONSTANT TASTO_6=18
27 CONSTANT TASTO_7=68
28 CONSTANT TASTO_8=36
29 CONSTANT TASTO_9=20
30 CONSTANT TASTO_0=40
31 CONSTANT TASTO_ASTERISCO=72
32 CONSTANT TASTO_CANCELLETTO=24
35 '------- INIZIO PROG -----------
36 DIM COMB(6) AS WORD
37 SETIO=&HF
38 CADS=0
40 LASTCAR=0
45 NCAR=0
47 LASTCAR=0
50 GOSUB 185
55 IF !PULS THEN 47
60 IF PULS=LASTCAR THEN 50
65 LASTCAR=PULS
66 ' usbout=PULS & ""
70 GOSUB 160
71 IF PULS =TASTO_ASTERISCO THEN 45
72 NCAR++
73 COMB(NCAR)=PULS
90 IF NCAR <5 THEN 50
91 IF COMB(5) <> TASTO_CANCELLETTO then 50
95 IF COMB(1)=TASTO_1 AND COMB(2)=TASTO_4 THEN 115
100 IF NCAR<6 THEN 50
105 NCAR--
110 GOTO 50
115 IF COMB(3)<>TASTO_9 THEN 50
116 IF COMB(4)=TASTO_3 THEN 135
117 IF COMB(4)=TASTO_2 THEN 140
120 goto 50
130 '---------------------------APERTURA CANCELLO RITARDATA
135 OUT=128 ' ACCENDO IL LED DEL PULSANTE LO LASCIO ROSSO
136 WAITS 30 ' ATTENDO 5 SECONDI
139 '---------------------------APERTURA CANCELLO
140 OUT= 384 'Setto il bit dell'apertura cancello con led pulsante acceso
145 WAITMS 250
150 OUT= 0 'Resetto il bit dell'apertura cancello
155 GOTO 45
160 '----------------------------ACCENDO LED PER INDICARE LA PRESSIONE DEL PULSANTE
165 OUT=128 'Accendo il led
170 WAITMS 100
175 OUT=0 'Spengo il led
180 RETURN
185 '----------------------------TORNO I CARATTERI PREMUTI SULLA TASTIERA
190 USCITA=16
195 GOSUB 240
200 IF PULS THEN 230
205 USCITA=32
210 GOSUB 240
215 IF PULS THEN 230
220 USCITA=64
225 GOSUB 240
230 RETURN
235 '----------------------------TORNO IL CARATTERE PREMUTO SULLA TASTIERA
240 PULS=0
245 out=USCITA
250 ING=INP AND 15
255 IF !ING THEN 265
260 PULS=ING OR USCITA
265 RETURN

Scarica il file: apricancello.zip

[ Back to top ] [ Home ]

PPTEA

Menu:

Apricancello